Sommen.Als

[Hidde]

Hallo iedereen,

 

Dit is de eerste keer dat ik hier post dus neem me niet kwalijk als ik vergeet informatie bij te voegen dat benodigd is om mijn probleem op te lossen.

 

Probleem: Ik wil een sommen.als formule maken die waarden opteld uit een tabel op basis van een aantal dropdown menu's.

Ik kan geen manier vinden waarop ik dit zou kunnen doen.

 

Hieronder mijn voorbeeld hoe ik het nu heb gedaan, voor 1 dropdown:

 

Tabel:

 

Kolom A : Kolom B

Jaar       : Orders 

2014      : 1

2015      : 1

 

 

=SOMMEN.ALS(Tabel2[Orders];Tabel2[Jaar];ALS(B4="All"; ----- ; B4)

 

Optelbereik: Het optelbereik dat ik wil optellen als de criteria overeenkomen.

Criteriabereik: Het criteriabereik, in dit geval de kolom met alle jaargetallen, 2014 en 2015.

Criteria: Het criteria dat ik wil gebruiken. Het werkt zo, als B4 = "All", dan wil ik dat hij 2014 EN 2015 selecteert waardoor ik dus beide criteria krijg en alle data krijg, en als B4 niet = "All", dan wil ik dat hij B4 gebruikt (2014 OF 2015)

 

Deze formule geeft me dus wel de juist data als B4 één criteria is (2014 of 2015), wat dus resulteert in 1.

Deze formule geeft me een 0 waarde als ik "All" invoer, terwijl ik dus de waarde 2 wil hebben (het totaal).

 

Wat voor waarde moet ik geven bij de waarde als waar, om alle data te krijgen.

Of is er een andere formule die me kan helpen?

 

Met vriendelijke groeten,

Hidde

18 november 2015 aangepast door Hidde

[Hidde]

Ik ben zelf achter het antwoord gekomen.

De formule die ik gebruik bij cijfers:

 

=SOMMEN.ALS(Tabel2[Orders];Tabel2[Jaar];ALS(B4="All";">" & 0; B4)

 

De formule die ik gebruik bij tekst:

 

=SOMMEN.ALS(Tabel2[Orders];Tabel2[Jaar];ALS(B4="All";"*"; B4)

[alpha]

Het kan ook in 1 formule.

Als 2014 in A2 staat en 2015 in A3.

Als in B2 en B3 de bijbehorende aaltallen staan.

Als in B4 staat (naar keuze): 2014, 2015, of All .

Typ dan in de cel waarin je het resultaat wil zien:

=ALS(B4="all";SOM(B2:B3);SOMMEN.ALS(B2:B3;A2:A3;B4))

Als je de bereiken namen hebt gegeven, kun je de bereiken evt. vervangen door die namen, aldus:

=ALS(B4="all";SOM(Tabel2[Orders]);SOMMEN.ALS(Tabel2[Orders];Tabel2[Jaar];B4))

19 november 2015 aangepast door alpha

[Hidde]

Beste alpha, 

 

Ik zal deze manier uitproberen, al wordt de formule dan denk ik langer dan degene die ik op dit moment heb:

Ik weet niet of je iets kan maken van deze formule, maar dit is degene die ik op dit moment gebruik.

=SOMMEN.ALS(ALS($A$4="Revenue Total";Tabel1[Revenue Total];ALS($A$4="Revenue (ex shipping)";Tabel1[Revenue (ex shipping)];
ALS($A$4="Revenue (shipping)";Tabel1[Revenue (shipping)];ALS($A$4="Orders";Tabel1[Orders];
ALS($A$4="AOV (incl shipping)";Tabel1[AOV (incl shipping)];ALS($A$4="AOV (ex shipping)";Tabel1[AOV (ex shipping)];
ALS($A$4="Items";Tabel1[Items];
ALS($A$4="AO Items";Tabel1[AO Items];ALS($A$4="Ordermarge";Tabel1[Ordermarge];
ALS($A$4="Average Item Value";Tabel1[Average Item Value];ALS($A$4="Shipping Costs Total";Tabel1[Shipping Costs Total];
ALS($A$4="Shipping Costs Marge";Tabel1[Shipping Costs Marge];ALS($A$4="Average Shipping Costs";Tabel1[Average Shipping Costs];
ALS($A$4="Visitors";Tabel1[Visitors];ALS($A$4="Unique Visitors";Tabel1[Unique Visitors];
ALS($A$4="Average Session Duration (s)";Tabel1[Average Session Duration (s)];ALS($A$4="Conversion Rate (sessions)";Tabel1[Conversion Rate (sessions)];
ALS($A$4="Conversion Rate (visitors)";Tabel1[Conversion Rate (visitors)];ALS($A$4="Bounce Rate";Tabel1[Bounce Rate];
ALS($A$4="New Customers";Tabel1[New Customers];ALS($A$4="Returning Customers";Tabel1[Returning Customers];
ALS($A$4="Loyal Customers";Tabel1[Loyal Customers];ALS($A$4="Cart Abandon Rate";Tabel1[Cart Abandon Rate];
ALS($A$4="Organic Traffic";Tabel1[Organic Traffic];ALS($A$4="CPC Traffic";Tabel1[CPC Traffic];
ALS($A$4="Referral Traffic";Tabel1[Referral Traffic];"Error")))))))))))))))))))))))));
Tabel1[View 1];ALS($A$2="All";"*";$A$2);
Tabel1[View 2];ALS($C$2="All";"*";$C$2);
Tabel1[Device];ALS($E$2="All";"*";$E$2);
Tabel1[System];ALS($G$2="All";"*";$G$2);
Tabel1[Traffic];ALS($I$2="All";"*";$I$2);
Tabel1[Channel];ALS($L$2="All";"*";$L$2);
Tabel1[Year];ALS($C$5="All";">" & 0;$C$5);
Tabel1[Month];A7;
Tabel1[Real/Target];$B$5)

Het gaat om ongeveer 20 data variabelen, die ik wil zien in dezelfde tabel, als ik er 1 selecteer in een drop down, en daarna maakt hij gebruikt van nog ongeveer 10 variabelen, waarop de data gebaseerd moet zijn.

19 november 2015 aangepast door Hidde

[alpha]

Over zo'n lange formule durf ik geen uitspraak te doen zonder het betreffende bestand in te zien.

En mét bestand misschien ook niet, dat kan ik vooraf niet zeggen.

[Hidde]

Het bestand is nogal vertrouwlijk haha.

Maar met de huidige formule die ik gebruik, werkt het, dus daar is ook geen verandering voor nodig.

Toch bedankt voor de hulp!

[alpha]

Vertrouwelijke gegevens kun je vervangen door andere.

Is de verwerking niet erg traag met zo'n lange formule?

[plongske]

zonder voorbeeld bestandje is het moeilijk te beoordelen, maar ik denk dat je die lange ALS kan vervangen door:

=INDIRECT("Tabel1["&A4&"]")